100 REM ORIGINAL BY      MR. JIM BUTTERFIELD
110 REM FROM BEST OF        TRANSACTOR VOL.2      BULLETIN 6
120 REM MODIFIED FOR   VIC BY ROY R ROBINSON       VANCOUVER B. C.
130 REM(604)437-8017
132 REM
135 REM SEE INSTR.
140 REM
150 PRINT"[147] DISK MEMORY DISPLAY  JIM BUTTERFIELD + RRR [146]"
160 DATA77,45,87,0,18,16,162,0,189
170 DATA157,64,06,232,224,16,208,245,76,193,254
180 FORJ=1TO9:READX:C$=C$+CHR$(X):NEXTJ
190 FORJ=1TO11:READX:D$=D$+CHR$(X):NEXTJ
200 PRINT" THERE ARE TWO          PROCESSORS:"
210 PRINT"  1) IEEE PROCESSOR"
220 PRINT"  2) DISK PROCESSOR"
230 PRINT"WHICH DO YOU WANT TO   PEEK ([158]1 OR[158] 2)"
240 GETG$:D=VAL(G$):IFD<>1ANDD<>2THEN240
250 PRINT"[156]YOUR CHOICE IS#[146]"D
260 PRINT" ENTER MEMORY ADDRESS   IN HEXADECIMAL:          [196][196][196][196][196][196][196][196][196][196][196]"
270 OPEN1,8,15:SC=36879
280 INPUTZ$:IFLEN(Z$)<>4THEN280
290 PRINTZ$:  PRINT"[145]                      ";
300 GOTO320
310 Z$=A$:IFLEN(Z$)<>4THEN280
320 GOSUB590:PRINT"  $"Z$"";
330 FORJ=1TO4:Y=ASC(MID$(Z$,J))
340 IFY<58THENY=Y-48
350 IFY>64THENY=Y-55
360 IFY<0ORY>16GOTO280
370 Y(J)=Y:NEXTJ:K=0:S=0:PRINT"";
380 ONDGOTO390,410:GOTO230
390 U=Y(3)*16+Y(4):V=Y(1)*16+Y(2)
400 GOSUB450:GOTO310
410 PRINT#1,C$;CHR$(Y(3)*16+Y(4));CHR$(Y(1)*16+Y(2));D$
420 PRINT#1,"M-W";CHR$(4);CHR$(16);CHR$(1);CHR$(224)
430 PRINT#1,"M-R";CHR$(4);CHR$(16):GET#1,X$:IFX$=CHR$(224)GOTO430
440 U=64:V=18:GOSUB450:GOTO310
450 PRINT#1,"M-R"CHR$(U);CHR$(V)
460 GET#1,X$:IFX$=""THENX$=CHR$(0)
470 PRINT" ";:X=ASC(X$)/16
480 FORJ=1TO2:X%=X:X=(X-X%)*16:IFX%>9THENX%=X%+7
490 PRINTCHR$(X%+48);:NEXTJ
500 U=U+1:IFU=256THENU=0:V=V+1:IFV=256THENV=0
510 S=S+1:IFS=4THENGOSUB580
520 K=K+1:IFK<8GOTO450
530 Y(0)=0:Y(4)=Y(4)+8:J=4
540 IFY(J)>15THENY(J)=Y(J)-16:J=J-1:Y(J)=Y(J)+1:GOTO540
550 PRINT"[146]"
560 A$="":PRINT;:FORJ=1TO4:Y=Y(J):IFY>9THENY=Y+7
570 A$=A$+CHR$(Y+48):NEXTJ:PRINT"[145]":RETURN
580 PRINTSPC(10);:RETURN
590 GETA$:IFA$<>" "THENRETURN
600 PRINT:PRINT"..?"
610 GETA$:IFA$="A"THEN650
620 IFA$="X"THEN:CLOSE1:END
625 IFA$="R"THENCLOSE1:GOTO200
630 IFA$<>" "THENGOTO610
640 RETURN
650 PRINT: PRINT" ENTER MEMORY ADDRESS    IN HEXADECIMAL:          [196][196][196][196][196][196][196][196][196][196][196]"
660 INPUTA$:GOTO310